SMTP alıcılarının SPF işleminin sonucunu ileti başlığına kaydetmeleri önerilir *ÖNERİ*. Eğer bir SMTP alıcısı bunu yapmak isterse, sınadığı her kimlik için burada tanımlanan "Received-SPF" başlık alanını kullanmalıdır *ÖNERİ*. Bu bilgi alıcı için tasarlanmıştır. (Gönderici için tasarlanmış bilgi İzahat (exp) bölümünde açıklanmıştı.)

"Received-SPF" başlık alanı bir izleme alanıdır ([RFC2822]'nin İzleme alanları bölümüne bakınız) ve mevcut başlıkların önüne, SMTP alıcı tarafından üretilen "Received:" alanının üstüne eklenmelidir *ÖNERİ*. İletideki diğer tüm "Received-SPF" başlık alanlarının üstünde görünmelidir *ZORUNLU*. Başlık alanının biçimi:

başlık-alanı     = "Received-SPF:" [AKBOŞ] sonuç KBOŞ [açıklama KBOŞ]
                   [ anah-değer-list ] CRLF

sonuç            = "Pass" / "Fail" / "SoftFail" / "Neutral" /
                   "None" / "TempError" / "PermError"

anah-değer-list  = anah-değer-çifti *( ";" [AKBOŞ] anah-değer-çifti )
                   [";"]

anah-değer-çifti = anahtar [AKBOŞ] "=" ( nokta-atom / tırnaklı-dizge )

anahtar          = "client-ip" / "envelope-from" / "helo" /
                   "problem" / "receiver" / "identity" /
                   "mechanism" / "x-" isim / isim

kimlik           = "mailfrom"   ; "MAIL FROM" kimliği için
                   / "helo"     ; "HELO"kimliği için
                   / isim       ; diğer kimlikler

nokta-atom       = <[RFC2822]'ye göre tırnaksız sözcük>
tırnaklı-dizge   = <[RFC2822]'ye göre tırnaklı dizge>
açıklama         = <[RFC2822]'ye göre açıklama dizgesi>
AKBOŞ            = <[RFC2822]'ye göre açıklamalı katlama boşlukları>
KBOŞ             = <[RFC2822]'ye göre katlama boşlukları>
CRLF             = <[RFC2822]'ye göre standart satır sonu dizgeciği>

Başlık alanı <sonuç>tan sonra <ip>, <gönderici>, ve <alan> gibi sonucu destekleyen bilgileri içeren "(...)" tarzı bir <açıklama> içermelidir *ÖNERİ*.

Aşağıdaki anahtar-değer çiftleri sonraki bir makine çözümlemesi için tasarlanmışlardır. SPF istemcileri SPF sonuçlarını doğrulayabilecek yeterli bilgiyi vermelidirler *ÖNERİ*. Yani, en azından "client-ip" ve "helo" anahtarlarıyla, "MAIL FROM" kimliği sınanmışsa "envelope-from" bulunmalıdır.

SPF istemcileri tarafından başka anahtarlar tanımlanabilir. Yeni bir anahtar geniş kabul görene kadar isimleri "x-" ile başlatılmalıdır.

SPF istemcileri "Received-SPF" başlık alanlarının geçersiz karakterler içermediğinden, aşırı uzun olmadığından ve göndericiden kaynaklanan bozucu veri içermediğinden emin olmalıdırlar *ZORUNLU*.

Üretilebilecek çeşitli başlık alanlarından örnekler:

Received-SPF: Pass (mybox.example.org: domain of
 myname@example.com designates 192.0.2.1 as permitted sender)
    receiver=mybox.example.org; client-ip=192.0.2.1;
    envelope-from=<myname@example.com>; helo=foo.example.com;

Received-SPF: Fail (mybox.example.org: domain of
                  myname@example.com does not designate
                  192.0.2.1 as permitted sender)
                  identity=mailfrom; client-ip=192.0.2.1;
                  envelope-from=<myname@example.com>;