Bir kural, bir dizi kural ismini yan yana getirerek aslında basit değerlerin bir dizgesini tanımlayabilir. Örneğin,

foo         =  %x61           ; a

bar         =  %x62           ; b

mumble      =  foo bar foo

<mumble> kuralı küçük harfli dizge "aba" ile eşleşir.

Ayraçlar veya dizge parçaları çevresinde düzgün doğrusal boşluklara izin verilmesini isteyen bir dilbilgisinin açıkça belirtirmesi gerekir. Yüksek seviyeden kurallar arasında kullanmak üzere böyle boşluklarla ilgili "çekirdek" kurallar tanımlamak çoğunlukla kullanışlı olmaktadır. "Çekirdek" kurallar, bir sözel çözümleyici için veya ana kural kümesinin basit bir parçası olarak şekillenebilir.

Birbirleri yerine kullanılabilecek elemanlar bölü çizgisi ("/") ile ayrılır. Yani,

foo / bar

<foo> veya <bar>'dan biri kabul edilecektir anlamına gelir.

Bazan bir ikame listesini dilimler halinde belirtmek uygun olur. Yani, birden fazla ikamesi olan bir kuralın ikameleri ek kural tanımları ile belirtilebilir. Aynı ana kural kümesinden türemiş bağımsız belirtimler (bağımsız değişken listeleri şeklinde oluşan) olmadıkça bu kısmen kullanışlıdır. Bu eklemeli tanımlara ABNF'de şöyle izin verilir:

eskikural     =/ ek-ikameler

Şöyle bir kural kümesi,

kuralkümesi  =  alt1 / alt2

kuralkümesi  =/ alt3

kuralkümesi  =/ alt4 / alt5

şu belirtimle aynıdır:

kuralkümesi  =  alt1 / alt2 / alt3 / alt4 / alt5

İkame sayısal değerler, değer aralığı için bir tire imi ("-") kullanılarak tek parça halinde belirtilebilir. Örneğin,

RAKAM       =  %x30-39

şuna eşdeğerdir:

RAKAM       =  "0" / "1" / "2" / "3" / "4" / "5" / "6" /

                    "7" / "8" / "9"

Ulanan sayısal değerlerle sayısal değer aralıkları aynı dizgede belirtilemez. Ulama için bir sayısal değer noktalı gösterimle belirtilebilirken bir değer aralığını belirtmek için tire kullanılır. Bu nedenle, satır sonu dizilimleri arasında basılabilir bir karakterin belirtilmesi için belirtim şöyle olabilirdi:

krk-satırı = %x0D.0A %x20-7E %x0D.0A

Parantez içine alınmış elemanlar içerildikleri sıra değişmemek üzere tek bir eleman olarak ele alınırlar.

elem (foo / bar) blat

şeklinde bir tanım, (elem foo blat) veya (elem bar blat) ile eşleşecektir.

elem foo / bar blat

ise (elem foo) veya (bar blat) ile eşleşir.

Bu nedenle üstteki biçim yerine şu biçim önerilir:

(elem foo) / (bar blat)

Böylece arasıra düzgün okuyanların tanımı yanlış yorumlaması önlenmiş olur.

Dizilim grubu gösterimi ayrıca serbest yazı içinde de kullanılır.

"*" işleci bir elemanın önüne konulduğunda yineleme belirtir. Örneğin,

<a>*<b>eleman

gösteriminde <a> ve <b> isteğe bağlı ondalık değerler olmak üzere içinde en az <a> veya en çok <b> sayıda eleman içerebilen oluşumlar tanımlanmaktadır.

Öntanımlı değerler sıfır ve sonsuz olmak üzere, *<eleman> sıfır dahil her sayıya izin verirken, 1*<eleman> en az 1, 3*3<eleman> tam olarak 3 ve 1*2<eleman> ise bir ya da ikisine izin verir.

<n>eleman

kuralı

<n>*<n>eleman

kuralına eşdeğerdir. Yani, tam olarak <n> <eleman> oluşumu belirtir. Bu bakımdan, 2RAKAM 2 rakamlı bir sayı belirtirken 3HARF 3 harften oluşan bir dizgeyi belirtecektir.

Köşeli ayraç içine alma, isteğe bağlı dizilim belirtir:

[foo bar]

ile

*1(foo bar).

eşdeğerdir.

Bir noktalı virgül, satır sonuna kadar devam eden bir açıklamayı başlatır. Bu, belirtimle birlikte açıklamaları da içermenin basit bir yoludur.

Buraya kadar açıklanan mekanizmalar en yüksekten en düşüğe (en sıkıdan en gevşeğe) aşağıdaki öncelik sıralamasına uyarlar:

Dizgeler, İsimler
Açıklamalar
Değer aralıkları
Yineleme
Gruplama, İsteğe bağlılık
Ulama
İkame

İkame işlecinin kullanımı, ulamalarla karıştırıldığında karışıklığa yol açabilir.